Split-plot designs are used when the levels of some treatment factors are more difficult to change during the experiment than those of others. The designs have a nested structure.
A split-plot design is characterized by separate random assignments of levels of factors, where levels of some factor are assigned to larger experimental units called whole plots. Each whole plot is divided into smaller units, called split-plots, and levels of another factor are randomly assigned to split-plots.
Example 1. An experiment is to compare the yield of three varieties of oats (factor \(A\) with \(a=3\) levels) and four different levels of manure (factor \(B\) with \(b=4\) levels). Since it is easier to plant a variety of oat in a large field, the experimenter uses a split-plot design as follows: 1. To divide the field into six equal sized plots (whole plots), and the varieties of oat are assigned to the whole plots according to a completely randomized design. 2. Each whole plot is divided into 4 plots (split plots) and the four levels of manure are assigned completely at random to the 4 split plots within each block. Hence the levels of manure are assigned according to a general complete block design where each whole plot is a block.
Blocks are quite often used in a split-plot design as illustrated by the following example.
Example 2. An experiment is to compare the yield of three varieties of oats (factor \(A\) with \(a=3\) levels) and four different levels of manure (factor \(B\) with \(b=4\) levels). Suppose 6 farmers agree to participate in the experiment and each will designate a farm field for the experiment (blocking factor with \(s=6\) levels). Since it is easier to plant a variety of oat in a large field, the experimenter uses a split-plot design as follows: 1. To divide each block into three equal sized plots (whole plots), and varieties of oat are assigned to the whole plots according to a randomized block design. 2. Each whole plot is divided into 4 plots (split-plots) and the four levels of manure are assigned to the split plots according to a general complete block design where the whole plots are blocks.
Let us consider Example 1. Let \(Y_{iujt}\) denote the observation from the \(u\)th assignment of level \(i\) of Factor \(A\), and \(t\)th assignment from the \(j\)th level of Factor \(B\). If we only consider Factor \(A\), the design is a completely randomized design and the model would be
\[ Y_{i u}=\mu+\alpha_i+\epsilon_{i u}. \] Now with Factor \(B\) being assigned to the split plots, the model becomes
\[ \begin{gathered} Y_{i u j t}=\mu+\alpha_i+\epsilon_{i u}^W \\ +\beta_j+(\alpha \beta)_{i j}+\epsilon_{j t(i u)}^S \\ \epsilon_{i u}^W \sim N\left(0, \sigma_W^2\right), \quad \epsilon_{j t(i u)}^S \sim N\left(0, \sigma_S^2\right) \\ \epsilon_{i u}^W \text{ and } \epsilon_{j t(i u)}^S \text{ mutually independent}\\ i=1, \ldots, a ; \quad u=1, \ldots, \ell ; j=1, \ldots, b ; t=1, \ldots, m. \end{gathered} \]
Note there are two error terms, one for the whole plot and one for the split plot. The whole error term \(\epsilon_{i u(h)}^W\) denotes the random effects of the whole plot.
If there blocks are used as in Example 2, the model then includes block effects. It becomes as follows:
\[\begin{equation} Y_{h i u j t}=\mu+\theta_h+\alpha_i+\epsilon_{i u(h)}^W \\ +\beta_j+(\alpha \beta)_{i j}+\epsilon_{j t(hi u)}^S \tag{1} \end{equation}\]
\[ \begin{gathered} \epsilon_{i u (h)}^W \sim N\left(0, \sigma_W^2\right), \quad \epsilon_{j t(hi u)}^S \sim N\left(0, \sigma_S^2\right) \\ \epsilon_{i u}^W \text{ and } \epsilon_{j t(hi u)}^S \text{ mutually independent}\\ i=1, \ldots, a ; \quad u=1, \ldots, \ell ; j=1, \ldots, b ; t=1, \ldots, m. \end{gathered} \] Notations in the model:
To show how the analysis can be done for a split-plot design, we consider the case of equal sample sizes and randomized complete block designs for each of the treatment factors. There are then \(s\) blocks, each of which is divided into \(a\) whole plots, and each of these is subdivided into \(b\) split plots, giving a total of \(s a b\) observations.
\[\begin{equation} Y_{h i j}=\mu+\theta_h+\alpha_i+\epsilon_{i(h)}^W \\ +\beta_j+(\alpha \beta)_{i j}+\epsilon_{j(h i)}^S, \tag{2} \end{equation}\]
\[ \begin{gathered} \epsilon_{i(h)}^W \sim N\left(0, \sigma_W^2\right), \quad \epsilon_{j(h i)}^S \sim N\left(0, \sigma_S^2\right),\\ h=1, \ldots, s; \quad i=1, \ldots, a ; \quad u=1, \ldots, \ell ; j=1, \ldots, b \end{gathered} \] The ANOVA table is given below.
\[ \begin{array}{llllc} \hline \text { Source of variation } & \text { Degrees of freedom } & \text { Sum of squares } & \text { Mean square } & \text { Ratio } \\ \hline \text { Block (Subjects) } & s-1 & s s \theta & - & - \\ A & a-1 & s s A & m s A & m s A / m s E_W \\ \text { Whole-plot error } & (s-1)(a-1) & s s E_W & m s E_W & - \\ \hline \text { Whole-plot total } & s a-1 & s s W & m s B & - \\ B & b-1 & s s B & m s B / m s E_S \\ A B & (a-1)(b-1) & s s(A B) & m s(A B) & m s(A B) / m s E_S \\ \text { Split-plot error } & a(b-1)(s-1) & s s E_S & m s E_S & \\ \hline \text { Total } & a b s-1 & s s t o t & & \end{array} \]
Computational formulae
\[ \begin{array}{rlrl} s s \theta & =a b \Sigma_h \bar{y}_{h\cdot\cdot}^2-s a b \bar{y}_{\cdot\cdot\cdot}^2 & s s W & =b \Sigma_h \Sigma_i \bar{y}_{h i \cdot}^2-s a b \bar{y}_{\ldots}^2 \\ s s A & =s b \Sigma_i \bar{y}_{\cdot i \cdot}^2-s a b \bar{y}_{\cdot\cdot\cdot}^2 & & s s B=s a \Sigma_j \bar{y}_{\cdot\cdot j}^2-s a b \bar{y}_{\cdot\cdot\cdot}^2 \\ s s E_W & =s s W-s s \theta-s s A & & s s(A B)=s \Sigma_i \Sigma_j \bar{y}_{. i j}^2-s b \Sigma_i \bar{y}_{. i .}^2 \\ s s t o t & =\Sigma_h \Sigma_i \Sigma_j y_{h i j}^2-s a b \bar{y}_{\cdot\cdot\cdot}^2 & & -s a \Sigma_j \bar{y}_{. j}^2+s a b \bar{y}_{\ldots .}^2 \\ & & s s E_S= & s s t o t-s s W-s s B-s s(A B) \end{array} \]
Please note that test for equal effects for \(A\) requires the whole plot error as the denominator. Because the whole-plot error has fewer degrees of freedom than the splot-plot error, the test of factor A (whose levels are assigned to whole plots) has less power than the test for factor B (whose levels are assigned to split plots).
The contrasts for the main effects of \(A\) and \(B\), and the interaction contrasts are estimated by \[ \begin{aligned} \sum_i c_i \hat{\alpha}_i^* &=\sum_i c_i \bar{y}_{. i .} \\ \sum_j d_j \hat{\beta}_j^* &=\sum_j d_j \bar{y}_{. . j} \\ \sum_i \sum_j k_{i j} \widehat{(\alpha \beta)}_{i j} &=\sum_i \sum_j k_{i j} \bar{y}_{. i j} \end{aligned} \] where \(\sum_i c_i=0, \sum_j d_j=0\), and \(\sum_i k_{i j}=\sum_j k_{i j}=0\).
Note the variance of a contrast of main effects of factor A depends on the whole plot error variance. Therefore, use the whole-plot error when constructing confidence intervals for the contrast. The variances of contrasts of main effects of B and for the interaction effects only depend on the error variance \(\sigma^2\). Use the split-plot error for confidence intervals for those contrasts.
Suppose Factor A is assigned to whole plots within each block and Factor B assigned to split plots. The following is the SAS code for the analysis of the split-plot model
proc mixed;
class A B Block;
model Y = A B A*B;
random Block A*Block;
run;The statements lsmeans, estimate, contrast are also available and used in the same way as for other models.
An experiment on the yield of three varieties of oats (factor \(A\) ) and four different levels of manure (factor B) was described by F. Yates in his 1935 paper Complex Experiments. The experimental area was divided into \(s=6\) blocks. Each of these was then subdivided into \(a=3\) whole plots. The varieties of oats were sown on the whole plots according to a randomized complete block design (so that every variety appeared in every block exactly once). Each whole plot was then divided into \(b=4\) split plots, and the levels of manure were applied to the split plots according to a randomized complete block design (so that every level of \(B\) appeared in every whole plot exactly once). The design, after randomization, is shown in Table 19.3, together with the yields in quarter pounds. Model (1) was used.
* oats.sas, oats experiment, Table 19.3, p710;
;
DATA OAT;
INPUT BLOCK WP A B Y;
LINES;
1 1 2 3 156
1 1 2 2 118
1 1 2 1 140
1 1 2 0 105
1 2 0 0 111
1 2 0 1 130
1 2 0 3 174
1 2 0 2 157
1 3 1 0 117
1 3 1 1 114
1 3 1 2 161
1 3 1 3 141
2 1 2 2 109
2 1 2 3 99
2 1 2 0 63
2 1 2 1 70
2 2 1 0 80
2 2 1 2 94
2 2 1 3 126
2 2 1 1 82
2 3 0 1 90
2 3 0 2 100
2 3 0 3 116
2 3 0 0 62
3 1 2 2 104
3 1 2 0 70
3 1 2 1 89
3 1 2 3 117
3 2 0 3 122
3 2 0 0 74
3 2 0 1 89
3 2 0 2 81
3 3 1 1 103
3 3 1 0 64
3 3 1 2 132
3 3 1 3 133
4 1 1 3 96
4 1 1 0 60
4 1 1 2 89
4 1 1 1 102
4 2 0 2 112
4 2 0 3 86
4 2 0 0 68
4 2 0 1 64
4 3 2 2 132
4 3 2 3 124
4 3 2 1 129
4 3 2 0 89
5 1 1 1 108
5 1 1 2 126
5 1 1 3 149
5 1 1 0 70
5 2 2 3 144
5 2 2 1 124
5 2 2 2 121
5 2 2 0 96
5 3 0 0 61
5 3 0 3 100
5 3 0 1 91
5 3 0 2 97
6 1 0 2 118
6 1 0 0 53
6 1 0 3 113
6 1 0 1 74
6 2 1 3 104
6 2 1 2 86
6 2 1 0 89
6 2 1 1 82
6 3 2 0 97
6 3 2 1 99
6 3 2 2 119
6 3 2 3 121
;
run;
proc mixed data=oat;
class A B Block;
model Y=A B A*B;
random Block A*Block;
lsmeans A B/cl pdiff adjust=Tukey;
lsmeans B/cl pdiff=control('0') adjust=Dunnett alpha=0.01;
run;The last statement produces 99% simultaneous confidence intervals for treatment-versus-control comparisons using Dunnett’s method. Compare the results with those provided in Sec 19.3 where step-by-step construction of the confidence intervals were shown.
Note in the above program we did not use WP. Alternatively we can replace A*Block in the random statement by WP(A*BLOCK) to specifically define the whole-plot error. Note the whole plots are nested within A by Block. You must claim WP as a factor in the class statement.
proc mixed data=oat;
class A B Block WP;
model Y=A B A*B;
random Block WP(A*BLOCK);
lsmeans A B/cl pdiff adjust=Tukey;
lsmeans B/cl pdiff=control('0') adjust=Dunnett alpha=0.01;
run;In a split-plot design with Factor A assigned to whole plots and Factor B assigned to split-plots, it is possible that there are no blocks for factor 1. An example is the cigarette experiment described on page 760. Suppose there are \(a\ell\) whole plots where \(a\) is the number of levels of factor \(A\). The levels of factor \(A\) are assigned to the whole plots in the completed randomized design and each level is replicated \(\ell\) times, and levels of factor \(B\) are assigned to the split-plots as general complete block design where the whole plots are blocks.
\[ \begin{gathered} Y_{i u j t}=\mu+\alpha_i+\epsilon_{i u}^W \\ +\beta_j+(\alpha \beta)_{i j}+\epsilon_{j t(i u)}^S \\ \epsilon_{i u}^W \sim N\left(0, \sigma_W^2\right), \quad \epsilon_{j t(i u)}^S \sim N\left(0, \sigma_S^2\right) \\ \epsilon_{i u}^W \text{ and } \epsilon_{j t(i u)}^S \text{ mutually independent}\\ i=1, \ldots, a ; \quad u=1, \ldots, \ell ; j=1, \ldots, b ; t=1, \ldots, m. \end{gathered} \]
Note The whole error term \(\epsilon_{i u(h)}^W\) denotes the random effects of the whole plot. In some books it is denoted by \(\text{WP}_{u(i)}\). The whole plots are now nested in \(A\). The SAS code is given below:
proc mixed data=yourdata;
class WP A B;
model time=A B A*B;
random WP(A);
run;If the treatments assigned to the split-plots represent combinations of two factors, say, \(C\) and \(D\), the above model is equivalent to the following model that includes the interaction terms.
proc mixed data=yourdata;
class WP A C D;
model time=A C D C*D A*C A*D A*C*D;
random WP(A);
run;We will then be able to test the interaction effects.